在VB编程的时候，很多人肯定碰到过开启程序以后程序界面会“没反应”，“没有响应”，但是我们代码要求执行的任务还在正常的进行，任务执行完毕，程序界面又恢复正常，尤其是使用循环的时候很容易出现程序没响应的现象，这类问题怎么解决呢？用DoEvents就可以解决。举例：

Private Sub DelayTime(num As Long)
Dim star, ends As Long
star = timeGetTime
ends = star
Do While ends - star < num
ends = timeGetTime
DoEvents
Loop
End Sub

DoEvents 是： 转让控制权，以便让操作系统处理其它的事件。最简单的理解，比如你要在某个耗时很多的过程中（最常见的是循环），还要响应某个操作－比如控制进度条的显示，那就需要加入DoEvents
但是，当看到这句话时，脑子里面的概念很模糊，只有一个浅薄的认识。打个比方：如果现在有一个从1 到100000000的循环，有一点编程常识的人肯定知道在这个耗时较长的循环过程中，基本上是不能进行别的操作（当然不排除一些特别的情况），但是因为某些特别的要求，你要在循环过程中，进行其他操作，这时DoEvents 就派上用场了。
现在，大家应该明白了DoEvents 的主要功能了吧。下面举一些实例（基本上都是转载的），当然建议自己能亲自去试验，理解会深一些。

(注: '** 后面的代码表示如果在该处用了这个语句 以下代码中用到了一些api函数,请用vb附带的api浏览器查阅) （转载）

一. 基本用法:
1.窗体启动时如果要处理的事务太多或者用sleep函数暂停,造成其很久都不能出现时怎么办?
例如代码:
Private Sub Form_Load()
Show
'DoEvents
Sleep 5000
End Sub
通常容易想到在sleep前加个show,但还是不能达到预想的效果,窗体虽然出来了,但好象只达到了一半,如果加上第3句,将看到效果大不相同

2.如果有个很耗时的循环导致程序不响应,怎么办?
例如:
Dim L As Long
For L = 1 To 1000000
'DoEvents
Next L
如果无'DoEvents，在循环过程中程序无法处理事件，对于用户来说是不响应，无法控制的

3.想在循环中看到处理过程?
同样:
Dim L As Long
For L = 1 To 10000
'DoEvents
Text1.Text=Cstr(l)
Next L
无'DoEvents时将无法看到text1中的变化,而只在循环结束时看到最后结果

4.怎样中止循环?
如果有:
Private Sub Command3_Click()
Dim L As Long
Do
L = L + 1
Debug.Print L
DoEvents
Loop
End Sub
会发现当关闭窗口后，debug中的数据仍然在变化，说明并没结束
需要如下:
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
IsExit = False
Do While DoEvents
If IsExit = True Then Exit Do
L = L + 1
Loop
End Sub

Private Sub Command2_Click()''或者在form_unload模块中等等
IsExit = True
End Sub
其中 isexit是全局变量
有些人喜欢用end语句来结束程序，小程序固然可以，但当太大，或者调用了某些特殊的api函数后可能导致预想不到的错误。如果装载了许多东西在程序结束时不处理将卸载很慢，而且这种做法也极不符合正规软件的要求。总之end语句毛病很多，此不详谈，建议少使用甚至不使用。

二. 其基本用法大概就这些,现在解析其中的一些[难点]

1.为什么还是不能结束?
代码如下:
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
IsExit = False
Do
If IsExit = True Then Exit Do '句0
DoEvents '** 句1
Text1.Text = CStr(L) '** 句2
L = L + 1
Loop
End Sub

Private Sub Form_Load()
Static N As Long
N = N + 1
MsgBox N
End Sub

Private Sub Form_Unload(Cancel As Integer)
IsExit = True
End Sub

运行结果：启动时msg显示1，点击command1，text1在变化。此时再点form右上角的小差(关闭窗体)，发现vb运行控制上的按扭并没变化，说明程序还在运行。如果编译成程序后运行，按下ctrl+del+alt也可发现它还没结束。通过读代码，并没发现错误，怎么回事?

关键在于 句2 访问了控件的属性
代 码运行路径：当在DoEvents时，程序释放控制权，可以接收事件消息，form-unload事件只能从此处产生，假设此时关闭form，unload事件发生，即DoEvents后就运行unload代码，得到isexit=t,并且form卸载，代码返回到DoEvents之后，运行 句2，注意现在form 已经卸载了，text1从哪里来呢？

于是form重新装载，代码跳到form_load模块运行，所以在关闭窗体后可以看到msg 显示2，此模块运行完后再继续句2后面的代码，当下次循环遇到 句0时退出循环

另：既然退出了循环，怎么还不能结束？
vb程序规定(其实其他的windows语言一样)：窗体卸载时并不是立即卸载其模块代码，而只先卸载窗体中的控件和一些属性值，程序中最后一个窗体卸载时才完全卸载。
在这个单窗体程序中，form卸载时因为循环的控制无法卸载代码，失去了卸载代码的机会，导致再也不能卸载(因为没卸载代码,所以运行的 句2 是并不会出错)

另：既然再次运行了form_load代码，怎么看不见窗体？
因为程序启动时窗体的到显示的消息，而只运行此模块并没有(如果在msgbox n语句前加上show,就可以看到它了)
如何解决?
通过以上分析，应该很简单，把句1 和句2调换一下就可以了，关键：
<仔细分析代码是如何运行的,避免在form已经卸载了情况下访问控件>

2.用了DoEvents速度太慢了怎么办?
DoEvents的代价是速度变慢，但要程序响应又不得不用
其实DoEvents语句允许任何应用程序执行相关事件，而不仅仅是你自己的程序，所以变得很慢。
可以让它响应本程序事件动作，需要用到api函数GetInputState
例如用: If GetInputState() Then DoEvents  '来代替DoEvents可使循环运行更快

3.既要同时响应事件又要控件不变化，怎么办?
例如在一个长的循环中向listview控件中添加记录，无DoEvents时程序无响应，但有它时控件又闪的厉害
解决办法：
a.不一定每次循环都DoEvents，可以在适当时间时才用，至少没那么闪
b. 应用api函数 ValidateRect ，功能是使指定的矩型区域生效，通知Windows不对指定的区域进行重画
另：InvalidateRect 功能相反，同时需要用到函数 GetClientRect 取得指定对象的矩形区域应用*rect函数指定listview的矩形区不重画，即可避免闪烁(但还是要注意恢复重画，否则看不见了真实效果)

4.控时循环和变速齿轮
请看下面的代码：
Option Explicit
Private Declare Function timeGetTime Lib "winmm.dll" () As Long
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
Dim Kt As Long
IsExit = False
Do
Kt = timeGetTime()
'do something
L = L + 1
Text1.Text = L
'DoEvents '句 1
While timeGetTime - Kt < 50 '句 2
'While Abs(timeGetTime - Kt) < 50 '句 3
'While Abs(timeGetTime - Kt) And (Not IsExit) < 50 '句 4

DoEvents '句 5
Wend
'DoEvents '句 6
If IsExit Then Exit Do
Loop
End Sub

Private Sub Form_Unload(Cancel As Integer)
IsExit = True
End Sub
其中可用的代码(除去加"'" 号的代码)就是通常的控时循环代码
运行代码并不会出现错误，但在循环过程，请开启变速齿轮看看
当关闭齿轮时，将发现text1.text停止了，别慌，等一段时间它又会继续(这要看你设定的时间，这里是50毫秒，如果设定的太长text1.text将半天都没变化，这是怎么回事?
变速齿轮在启动时将hook.dll映射到你的程序地址运行，更改了timegettime()函数获取的时间
如果在句2和句3间插入debug.print timegettime,timegettime-kt 将发现，在关闭齿轮的瞬间后者变成了负值，timegettime变小了，所以才造成需要等很久
如果是编写游戏，而用户开了齿轮，那可就惨了

解决方案：
a.用句3代替句2，这个方法最简便，虽然不符实，但不会出问题，建议使用
b.不要句5，换用句6(这样就能达到效果吗?) 因为齿轮还是从DoEvents语句运行时才能插的进来，所以只要kt=timegettime 和 timegettime之间没有DoEvents就不会出错
ab.两种方法都有些小问题，但无大碍DoEvents有兴趣者请自己分析

5.程序怎么"死了"?
这只是一些人编写时没注意到的小问题，提醒一下：
同样用上面的代码，如果设定的时间太短，以至在代码运行到句2时已经超时了，句5将不能运行了，当然程序就死了哦，以防万一，加上句1，所以此时也只能用a方案来解决齿轮的问题了
有必要用句4代替句3 吗? 除非你设定的时间太长，人家想关闭你的程序要等上好半天。